[macro name=lr][l][r][endmacro]

;;;;;システム関連定義開始(いつか別のファイルに移します);;;;;

;色々流用してます

;システムボタンの表示のベースを指定
@eval exp="f.systopx = 220"
@eval exp="f.systopy = 557"

; ※システムボタン用の画像ファイルを指定
@eval exp="f.sysbtnimgs = [ 'save_button', 'load_button', 'config_button', 'skip_button', 'close_button']"

; ※ボタンがクリックされたときに呼び出されるシナリオファイルを指定
; （拡張子は必須）]
@eval exp="f.sysfile = ['save.ks', 'load.ks' , 'config.ks']"
;config.ksも後から追加する予定？

;システムボタンの表示座標の左上からの差分

@eval exp="f.sysx = [0, 110, 220, 330, 440, 600]"
@eval exp="f.sysy = [0, 0, 0, 0, -70]"

; システムボタン用処理の読み込み
@call storage="systembutton.ks"

;どこでもセーブ用(セーブ可能ラベルを自動生成)
@call storage="autoInsertLabel.ks"

;;;;;システム関連定義終了;;;;;


;;;;;絹虫マクロ定義開始;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;pタグ+labelマクロ+cmタグ
@macro name="plc"
@p
@label
@cm
@endmacro

;pタグ+labelマクロ+cmタグ(いつか↑に置換します)
@macro name="pcm"
@p
@label
@cm
@endmacro

;画像関連マクロ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;指定した前景レイヤを表示する(立ち絵表示に使用)
;記述例:@app_chara layer=0 storage=* pos=c
@macro name=app_chara
@backlay
@image layer="%layer" page=back storage="%storage" visible=true pos="%pos"
@trans method=crossfade time=100
@wt
@endmacro

;裏ページへ画像読み込み
;複数立ち絵を同時に表示する際に使用
;このタグで画像を読み込みsilkappでtransを実行
@macro name=load_chara
@image layer=%layer page="back" storage=%storage visible="true" pos=%pos
@endmacro

;立ち絵二枚同時表示用(02日目以降は不使用)
@macro name=app_chara2
@backlay
@image layer="%layer1" page=back storage="%storage1" visible=true pos="%pos1"
@image layer="%layer2" page=back storage="%storage2" visible=true pos="%pos2"
@trans method=crossfade time=100
@wt
@endmacro

;指定した前景レイヤを消す
;記述例:@dis_chara layer=2
@macro name=dis_chara
@backlay
@freeimage layer=%layer page=back
@trans method=crossfade time=100
@wt
@endmacro

;立ち絵二枚同時消し用(不要？)
@macro name=dis_chara2
@backlay
@freeimage layer=%layer1 page=back
@freeimage layer=%layer2 page=back
@trans method=crossfade time=100
@wt
@endmacro

;前景レイヤを全て消す
@macro name=dis_all_chara
@layopt layer="0" visible="false" page="back"
@layopt layer="1" visible="false" page="back"
@layopt layer="2" visible="false" page="back"
@layopt layer="3" visible="false" page="back"
@layopt layer="4" visible="false" page="back"
@layopt layer="5" visible="false" page="back"
@layopt layer="6" visible="false" page="back"
@layopt layer="7" visible="false" page="back"
@layopt layer="8" visible="false" page="back"
@layopt layer="9" visible="false" page="back"
@layopt layer="10" visible="false" page="back"
;@layopt layer="11" visible="false" page="back"
@trans method=crossfade time=100
@wt
@endmacro

;ココからトランジション関連マクロ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;トランジション用
@macro name=silktrans
@image layer="base" storage=%storage page="back" visible="true"
@trans method=%method rule=%rule from=%from stay=%stay time=%time vague=%vague
@wt canskip=%canskip
@endmacro

;黒背景用トランジション
@macro name=silkblack
@image layer="base" storage="black" page="back" visible="true"
@trans method=%method rule=%rule from=%from stay=%stay time=%time vague=%vague
@wt canskip=%canskip
@endmacro

;複数キャラ同時表示or消去時に使用(短時間でのtrans)
@macro name=silktrans_short
@trans method="crossfade" time="100"
@wt
@endmacro

;メッセージウィンドウ関連マクロ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;dis_mwindowとapp_mwindowは
;主にテキスト表示がない連続場面切り替え時に使用するかと。
;backのメッセージウィンドウを表示させる
@macro name=app_mwindow
@layopt layer="%layer" visible="true" page="back" opacity="%opacity" left="%left" top="%top"
@sysbtopt backvisible=true vertical=true left=&f.systopx top=&f.systopy
@endmacro

;backのメッセージウィンドウを非表示にする
@macro name=dis_mwindow
@layopt layer="%layer" visible="false" page="back" opacity="%opacity" left="%left" top="%top"
@sysbtopt backvisible=false
@endmacro

;選択肢用ウィンドウを表示
@macro name=app_cwindow
@layopt layer="%layer" visible="true" page="back" opacity="%opacity" left="%left" top="%top"
@trans method="crossfade" time="200"
@wt
@current layer="%layer" page="fore"
@endmacro

@macro name=dis_cwindow
@layopt layer="%layer" visible="false" page="back"
@trans method="crossfade" time="200"
@wt
@current layer=message0 page="fore"
@endmacro

;最初の部分で使用しているメッセージウィンドウ表示用
@macro name=full_message
@position layer=message0 left=30 top=50 width=740 height=500 marginl=30 margint=20 marginr=10 marginb=20 opacity=0 page="back" color="0xFFFFFF" visible="true"
@trans method="crossfade" time="500" layer="message0"
@wt
@endmacro

;セリフ以外のメッセージ表示する際に使用
;キャラの名前か顔を枠の外に表示させる場合は別マクロを作ろうかと
@macro name=normal_message
@sysbtopt forevisible=true vertical=true left=&f.systopx top=&f.systopy
@rclick jump="false" enabled="true" call="false"
;[eval exp="f.is_full = 0"]
@position layer="message0" frame="window1" page="fore" left=0 top=394 width=800 height=206 marginl=145 margint=70 marginr=110 marginb=40 visible=true
@layopt layer="message1" visible="false" page="back"
@layopt layer="message2" visible="false" page="back"
@current layer="message0"
@endmacro


;;臨時マクロ
;@macro name=change_datea
;@nowait
;@layopt layer="message1" visible="true" page="fore" opacity="255"
;@current layer="message1" page="fore"
;@locate x=10 y=100
;@endmacro
;
;@macro name=change_dateb
;(ここには日付切り替わり用の絵が表示されます)
;@waitclick
;@layopt layer="message1" visible="false" page="fore"
;@current layer="message0" page="fore"
;@endnowait
;@endmacro

;日付変更時の画像読み込み&トランジションマクロ
@macro name=change_date
@image storage=%storage layer=base page=back visible=true
@trans time=%time method=crossfade
@wt canskip="false"
@l
;@app_mwindow layer=message0
@endmacro


;;;;;絹虫マクロ定義終了;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

[return]